通常，在Delphi中，将使用“const”方法声明具有可变数量参数的函数。然而，为了与C编写的代码兼容，有一个很多未知的“varargs”指令可以添加到函数声明中(我在阅读Rudy的优秀“
Pitfalls of convering”文档时学到了)。
例如，可以在C中有一个函数，声明如下：
void printf(const char *fmt,...)
在德尔福，这将成为：
procedure printf(const fmt: PChar); varargs;
我的问题是：在实现使用“varargs”指令定义的方法时，如何获取堆栈的内容？
我希望有一些工具存在，像deva的va_start()，va_arg()和va_end()函数的翻译，但我找不到任何地方。
请帮忙！
PS：请不要在关于’为什么’或’数组的const’替代的讨论中漂流 – 我需要这样来为XBox游戏中的函数编写类似C的补丁(请参阅sourceforge上的Delphi XBox模拟器项目“Dxbx”详情)。
解决方法
好的，我看到你的问题的澄清意味着你需要在Delphi中实现C导入。在这种情况下，您需要自己实现varargs。
所需的基本知识是x86上的C调用约定：堆栈向下增长，C从右向左推动参数。因此，一个指向最后声明的参数的指针将在最后声明的参数的大小后增加，它将指向尾部参数列表。从那时起，它只是一个读取参数的问题，并将指针递增适当的大小以更深地移动到堆栈中。 32位模式下的x86堆栈通常是4字节对齐，这也意味着字节和字被传递为32位整数。
无论如何，这是演示程序中的帮助记录，显示如何读取数据。请注意，Delphi似乎以非常奇怪的方式传递扩展类型;然而，您可能不用担心，因为10字节的浮点在C中通常不被广泛使用，甚至不能在最新的MS C，IIRC中实现。
{$apptype console}
type
TArgPtr = record
private
FArgPtr: PByte;
class function Align(Ptr: Pointer; Align: Integer): Pointer; static;
public
constructor Create(LastArg: Pointer; Size: Integer);
// Read bytes,signed words etc. using Int32
// Make an unsigned version if necessary.
function ReadInt32: Integer;
// Exact floating-point semantics depend on C compiler.
// Delphi compiler passes Extended as 10-byte float; most C
// compilers pass all floating-point values as 8-byte floats.
function ReadDouble: Double;
function ReadExtended: Extended;
function ReadPChar: PChar;
procedure ReadArg(var Arg; Size: Integer);
end;
constructor TArgPtr.Create(LastArg: Pointer; Size: Integer);
begin
FArgPtr := LastArg;
// 32-bit x86 stack is generally 4-byte aligned
FArgPtr := Align(FArgPtr + Size,4);
end;
class function TArgPtr.Align(Ptr: Pointer; Align: Integer): Pointer;
begin
Integer(Result) := (Integer(Ptr) + Align - 1) and not (Align - 1);
end;
function TArgPtr.ReadInt32: Integer;
begin
ReadArg(Result,SizeOf(Integer));
end;
function TArgPtr.ReadDouble: Double;
begin
ReadArg(Result,SizeOf(Double));
end;
function TArgPtr.ReadExtended: Extended;
begin
ReadArg(Result,SizeOf(Extended));
end;
function TArgPtr.ReadPChar: PChar;
begin
ReadArg(Result,SizeOf(PChar));
end;
procedure TArgPtr.ReadArg(var Arg; Size: Integer);
begin
Move(FArgPtr^,Arg,Size);
FArgPtr := Align(FArgPtr + Size,4);
end;
procedure Dump(const types: string); cdecl;
var
ap: TArgPtr;
cp: PChar;
begin
cp := PChar(types);
ap := TArgPtr.Create(@types,SizeOf(string));
while True do
begin
case cp^ of
#0:
begin
Writeln;
Exit;
end;
'i': Write(ap.ReadInt32,' ');
'd': Write(ap.ReadDouble,' ');
'e': Write(ap.ReadExtended,' ');
's': Write(ap.ReadPChar,' ');
else
Writeln('Unknown format');
Exit;
end;
Inc(cp);
end;
end;
type
PDump = procedure(const types: string) cdecl varargs;
var
MyDump: PDump;
function AsDouble(e: Extended): Double;
begin
Result := e;
end;
function AsSingle(e: Extended): Single;
begin
Result := e;
end;
procedure Go;
begin
MyDump := @Dump;
MyDump('iii',10,20,30);
MyDump('sss','foo','bar','baz');
// Looks like Delphi passes Extended in byte-aligned
// stack offset,very strange; thus this doesn't work.
MyDump('e',2.0);
// These two are more reliable.
MyDump('d',AsDouble(2));
// Singles passed as 8-byte floats.
MyDump('d',AsSingle(2));
end;
begin
Go;
end.