在机房收费系统中，有几个窗体需要导出数据到EXCEL表格中，如：学生上机记录查询窗体、学生充值记录查询窗体、收取金额查询窗体等。

前面的几篇总结，大家建议我不要把代码写的太详细，这样，不利于读者思考，以后我自己回顾的时候，可能也会看也不看，直接粘上所要用的东西，这样就起不到博客应该起到的作用。所以这篇博客，我会换一个方式来总结。

在导出EXCEL表格之前，首先要确保你的电脑已经安装了office。然后，可以编辑一个函数 ， 定义导出表格的过程，在使用的时候，直接调用就ok了，这样，系统中所有的导出表格的过程都可以用这一个函数，也减少了代码量。这个函数如下：

Public Sub ExportToExcel(FormName As Form,FlexgridName As String) '导出Excel表的过程
    Dim xlApp As Object 'Excel程序
    Dim xlBook As Object  'Excel工作薄
    Dim xlSheet As Object  'Excel工作表

    Screen.MousePointer = vbHourglass '鼠标指示为等待状态

    On Error GoTo Err_Proc
    Set xlApp = CreateObject("Excel.Application") '调用execel程序
    Set xlBook = xlApp.Workbooks.Add '添加工作薄
    Set xlSheet = xlBook.Worksheets(1) '添加工作单元

    '向工作单元中添加数据
    Dim i As Long
    Dim j As Integer
    
    With FormName.Controls(FlexgridName)
        For i = 0 To .Rows - 1 '行依次增加从0开始 外循环，外循环每增加1，内循环循环一周
            For j = 0 To .Cols - 1 '一行有.cols列 从0开始循环
                xlSheet.Cells(i + 1,j + 1).Value = "'" & .TextMatrix(i,j) '工作表中采用（x，y）坐标，都从1开始
            Next j
        Next i
    End With
    xlApp.Visible = True '设定Excel程序可见
    Screen.MousePointer = vbDefault '鼠标指针设为默认状态
    Exit Sub
Err_Proc:
    Screen.MousePointer = vbDefault '鼠标指针设为默认状态
    MsgBox "请确认您的电脑已安装Excel，或是否安装正确！",vbExclamation,"机房收费系统"
End Sub

简单方便，导出EXCEL表格。