delphi – OnClick事件覆盖

我的自定义类女巫来自TButton：

TLoginResultEvent = procedure (Sender: TObject; LoginResult: boolean) of object;
TLoginButton = class(TButton)
    private
      fLogin: TLoginChooser;
      fOnClick: TLoginResultEvent;
    public
      constructor Create(AOwner: TComponent); override;
      destructor Destroy; override;

      procedure OnClickResult(Sender: TObject; LoginResult: boolean);
    published
      property Login: TLoginChooser read fLogin write fLogin;
      property OnClick: TLoginResultEvent read fOnClick write fOnClick;
  end;

在构造函数中我添加了：

constructor TLoginButton.Create(AOwner: TComponent);
begin
  inherited;

  fOnClick := OnClick;
  OnClick := OnClickResult;
end;

但是当我点击按钮时它没有触发OnClickResult,我做错了什么？是否可以“覆盖”OnClick事件处理程序,还是应该隐藏它并制作示例OnResultClick事件？

解决方法

编写组件时,不应使用事件处理程序来实现自定义行为.相反,您应该覆盖调用这些事件处理程序的代码.在这种情况下,忘记设置OnClick.相反,只需添加

public
  procedure Click; override;

你的班级声明,并实施

procedure TLoginButton.Click;
begin
  inherited; // call the inherited Click method.
  // Do something new.
end;

开发人员使用该组件可以使用事件处理程序.组件编写者不应该自己使用它们.

如果您希望组件用户看到不同的“OnClick”方法,则必须自己实现,例如

type
  TLoginResultEvent = procedure(Sender: TObject; LoginResult: boolean) of object;

...

TLoginButton = class(TButton)
private
  FOnClick: TLoginResultEvent;
...
public
  procedure Click; override;
...
published
  property OnClick: TLoginResultEvent read FOnClick write FOnClick;
...

procedure TLoginButton.Click;
begin
  inherited;
  if Assigned(FOnClick) then
    FOnClick(Self,true); // or false...
end;

原文链接：https://www.f2er.com/delphi/101337.html

delphi – OnClick事件覆盖

解决方法

猜你在找的Delphi相关文章